Contract Address Details

// File: @openzeppelin/contracts/utils/ReentrancyGuard.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// File: @openzeppelin/contracts/utils/Address.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: contracts/RabbitHabit.sol


pragma solidity 0.8.20;




/**
 * @title RabbitHabit
 * @dev A simple betting contract where players can place bets and receive prizes based on the outcome.
 */
contract RabbitHabit is Ownable, ReentrancyGuard {
    using Address for address payable;

    uint256 private salt;
    uint256 public minBet;
    uint256 public maxBet;
    uint256 public stayBetCoefficient;
    uint256 public changedBetCoefficient;
    uint256 public constant COEFFICIENT_DENOMINATOR = 100;
    uint256 private constant DOORS_COUNT = 3;

    struct Bet {
        uint256 blockNumber;
        uint256 amount;
        uint256 firstBet;
        bool isChanged;
        uint256 salt;
        address player;
    }

    mapping(address => Bet[]) public bets;

    /**
     * @dev Emitted when a player places a bet.
     * @param player The address of the player placing the bet.
     * @param blockNumber The block number at which the bet is placed.
     * @param amount The amount of FTN sent with the bet.
     * @param firstBet The player's initial bet number.
     * @param isChanged Indicates whether the bet has been changed.
     */
    event BetPlaced(
        address indexed player,
        uint256 blockNumber,
        uint256 amount,
        uint256 firstBet,
        bool isChanged,
        uint256 salt
    );

    /**
     * @dev Emitted when a player claims their prize.
     * @param player The address of the player claiming the prize.
     * @param winAmount The amount of FTN won by the player.
     */
    event PrizeClaimed(address indexed player, uint256 winAmount);

    modifier notZero(uint256 number) {
        require(number > 0, "Number must be greater than zero");
        _;
    }

    constructor() Ownable(msg.sender) {
        minBet = 1 * 10 ** 18;
        maxBet = 100 * 10 ** 18;
        stayBetCoefficient = 300;
        changedBetCoefficient = 150;
    }

    receive() external payable {}

    /**
     * @dev Withdraws the FTN balance from the contract.
     * @param _amount The amount of FTN to withdraw.
     */
    function withdrawFTN(uint256 _amount) external onlyOwner {
        payable(msg.sender).sendValue(_amount);
    }

    /**
     * @dev Sets the minimum bet amount.
     * @param _minBet The new minimum bet amount.
     */
    function setMinBet(uint256 _minBet) external onlyOwner notZero(_minBet) {
        minBet = _minBet;
    }

    /**
     * @dev Sets the maximum bet amount.
     * @param _maxBet The new maximum bet amount.
     */
    function setMaxBet(uint256 _maxBet) external onlyOwner notZero(_maxBet) {
        maxBet = _maxBet;
    }

    /**
     * @dev Sets the stay bet coefficient.
     * @param _stayBetCoefficient The new stay bet coefficient.
     */
    function setStayBetCoefficient(
        uint256 _stayBetCoefficient
    ) external onlyOwner notZero(_stayBetCoefficient) {
        stayBetCoefficient = _stayBetCoefficient;
    }

    /**
     * @dev Sets the changed bet coefficient.
     * @param _changedBetCoefficient The new changed bet coefficient.
     */
    function setChangedBetCoefficient(
        uint256 _changedBetCoefficient
    ) external onlyOwner notZero(_changedBetCoefficient) {
        changedBetCoefficient = _changedBetCoefficient;
    }

    /**
     * @dev Allows a player to place a bet.
     * @param _firstBet The player's initial bet number.
     * @param _isChanged Indicates whether the bet has been changed.
     */
    function play(
        uint256 _firstBet,
        bool _isChanged
    ) external payable nonReentrant {
        require(
            address(this).balance >=
                (msg.value * stayBetCoefficient) / COEFFICIENT_DENOMINATOR,
            "Insufficient funds"
        );
        require(_firstBet > 0 && _firstBet < 4, "Incorrect bet number");
        require(
            msg.value >= minBet && msg.value <= maxBet,
            "Incorrect bet amount"
        );
        bets[msg.sender].push(
            Bet(
                block.number,
                msg.value,
                _firstBet,
                _isChanged,
                salt,
                msg.sender
            )
        );
        emit BetPlaced(
            msg.sender,
            block.number,
            msg.value,
            _firstBet,
            _isChanged,
            salt
        );
    }

    /**
     * @dev Allows a player to claim their prize.
     */
    function getPrize() external nonReentrant {
        uint256 winAmount = calculateTotalWin(msg.sender);
        require(winAmount > 0, "You have not win");
        delete bets[msg.sender];
        payable(msg.sender).sendValue(winAmount);
        emit PrizeClaimed(msg.sender, winAmount);
    }

    /**
     * @dev Retrieves the bets placed by a player.
     * @param _player The address of the player.
     * @return An array of Bet structs representing the player's bets.
     */
    function getBets(address _player) external view returns (Bet[] memory) {
        return bets[_player];
    }

    /**
     * @dev Calculates the total prize amount for a player.
     * @param _player The address of the player.
     * @return The total prize amount.
     */
    function calculateTotalWin(address _player) public view returns (uint256) {
        uint256 totalWin;
        for (uint256 i = 0; i < bets[_player].length; i++) {
            totalWin += calculateWin(_player, i);
        }
        return totalWin;
    }

    /**
     * @dev Calculates the prize amount for a specific bet of a player.
     * @param _player The address of the player.
     * @param _betIndex The index of the bet in the player's array of bets.
     * @return The prize amount for the bet.
     */
    function calculateWin(
        address _player,
        uint256 _betIndex
    ) public view returns (uint256) {
        Bet storage _bet = bets[_player][_betIndex];
        uint256 winNum = getRand(_bet.blockNumber, _bet.salt, _player);
        if (winNum == 0) {
            return 0;
        } else if (_bet.firstBet == winNum && !_bet.isChanged) {
            return (_bet.amount * stayBetCoefficient) / COEFFICIENT_DENOMINATOR;
        } else if (_bet.firstBet != winNum && _bet.isChanged) {
            return
                (_bet.amount * changedBetCoefficient) / COEFFICIENT_DENOMINATOR;
        } else {
            return 0;
        }
    }

    /**
     * @dev Estimates the potential reward for a given bet amount.
     * @param _amount The amount of FTN staked in the bet.
     * @param _isChanged A flag indicating whether the bet has been changed.
     * @return The estimated reward based on the bet amount and coefficients.
     * @notice This function provides an estimate of the potential reward for a bet
     * based on the specified amount and whether the bet has been changed.
     * If the bet has been changed (_isChanged is true), the reward is calculated
     * using the changed bet coefficient; otherwise, the stay bet coefficient is used.
     * The estimate does not represent the actual reward claimable by the player.
     * To claim the actual reward, use the 'getPrize' function after the bet outcome is determined.
     * @dev The coefficients used for the calculation are set by the contract owner.
     */
    function estimateAvialableReward(
        uint256 _amount,
        bool _isChanged
    ) public view returns (uint256) {
        if (_isChanged) {
            return (_amount * changedBetCoefficient) / COEFFICIENT_DENOMINATOR;
        } else {
            return (_amount * stayBetCoefficient) / COEFFICIENT_DENOMINATOR;
        }
    }

    /**
     * @dev Generates a pseudo-random number based on a past block's hash.
     * @param _blockNumber The block number to use for randomness.
     * @return The pseudo-random number.
     */
    function getRand(
        uint256 _blockNumber,
        uint256 _salt,
        address _player
    ) internal view returns (uint256) {
        require(block.number > _blockNumber, "Block number out of range");
        if (_blockNumber + 250 < block.number) {
            return 0;
        }
        return
            (uint256(
                keccak256(
                    abi.encodePacked((blockhash(_blockNumber)), _salt, _player)
                )
            ) % DOORS_COUNT) + 1;
    }

    /**
     * @dev Checks if a bet is a winning bet and calculates the potential prize.
     * @param _blockHash The hash of the block at which the bet was placed.
     * @param _firstBetNum The player's initial bet number.
     * @param _isChanged Indicates whether the bet has been changed.
     * @param _betAmount The amount of Ether staked in the bet.
     * @return The potential prize amount based on the bet outcome.
     * @dev The coefficients used for the calculation are set by the contract owner.
     */
    function checkWin(
        bytes32 _blockHash,
        uint256 _firstBetNum,
        bool _isChanged,
        uint256 _betAmount,
        address _player
    ) external view returns (uint256) {
        Bet storage _bet = bets[_player][bets[_player].length - 1];
        uint256 winNum = (uint256(
            keccak256(abi.encodePacked(_blockHash, _bet.salt, _player))
        ) % DOORS_COUNT) + 1;
        if (_firstBetNum == winNum && !_isChanged) {
            return (_betAmount * stayBetCoefficient) / COEFFICIENT_DENOMINATOR;
        } else if (_firstBetNum != winNum && _isChanged) {
            return
                (_betAmount * changedBetCoefficient) / COEFFICIENT_DENOMINATOR;
        } else {
            return 0;
        }
    }
}