Contract Address Details

// File: @openzeppelin/contracts/utils/Address.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: contracts/SuperMario.sol


pragma solidity 0.8.20;



/**
 * @title SuperMario
 * @dev A simple betting contract where users can bet on boxes, and if their bet matches the randomly selected box, they win a prize.
 */
contract SuperMario is Ownable {
    using Address for address payable;

    uint256 public minBet;
    uint256 public maxBet;
    uint256 public winCoefficient;
    uint256 public boxesCount;
    uint256 public constant COEFFICIENT_DENOMINATOR = 100;

    struct Bet {
        uint256 blockNumber;
        uint256 amount;
        uint256 betNumber;
    }

    mapping(address => Bet[]) public bets;

    /**
     * @dev Emitted when a user places a bet.
     * @param user The address of the user placing the bet.
     * @param blockNumber The block number at which the bet is placed.
     * @param amount The amount of FTN sent with the bet.
     * @param betNumber The user's selected box number.
     */
    event BetPlaced(
        address indexed user,
        uint256 blockNumber,
        uint256 amount,
        uint256 betNumber
    );

    /**
     * @dev Emitted when a user claims their prize.
     * @param user The address of the user claiming the prize.
     * @param winAmount The amount of FTN won by the user.
     */
    event PrizeClaimed(address indexed user, uint256 winAmount);

    modifier notZero(uint256 number){
        require(number > 0, "Number must be greater than zero");
        _;
    }

    constructor() Ownable(msg.sender) {
        minBet = 1 * 10 ** 17; //todo 18
        maxBet = 100 * 10 ** 17; //todo 18
        boxesCount = 5;
        winCoefficient = boxesCount * COEFFICIENT_DENOMINATOR;
    }

    receive() external payable {}

    /**
     * @dev Retrieves the bets placed by a user.
     * @param _user The address of the user.
     * @return An array of Bet structs representing the user's bets.
     */
    function getBets(address _user) public view returns (Bet[] memory) {
        return bets[_user];
    }

    /**
     * @dev Withdraws the FTN balance from the contract.
     * @param _amount The amount of FTN to withdraw.
     */
    function withdrawFTN(uint256 _amount) external onlyOwner {
        payable(msg.sender).sendValue(_amount);
    }

    /**
     * @dev Sets the minimum bet amount.
     * @param _minBet The new minimum bet amount.
     */
    function setMinBet(uint256 _minBet) external onlyOwner notZero(_minBet) {
        minBet = _minBet;
    }

    /**
     * @dev Sets the maximum bet amount.
     * @param _maxBet The new maximum bet amount.
     */
    function setMaxBet(uint256 _maxBet) external onlyOwner notZero(_maxBet) {
        maxBet = _maxBet;
    }

    /**
     * @dev Sets the win coefficient.
     * @param _winCoefficient The new win coefficient.
     */
    function setWinCoefficient(uint256 _winCoefficient) external onlyOwner notZero(_winCoefficient) {
        winCoefficient = _winCoefficient;
    }

    /**
     * @dev Sets the number of boxes available for betting.
     * @param _boxesCount The new number of boxes.
     */
    function setBoxesCount(uint256 _boxesCount) external onlyOwner notZero(_boxesCount) {
        boxesCount = _boxesCount;
    }

    /**
     * @dev Allows a user to place a bet on a box.
     * @param _betnum The user's selected box number.
     */
    function play(uint256 _betnum) external payable {
        require(
            address(this).balance >=
                (msg.value * winCoefficient) / COEFFICIENT_DENOMINATOR,
            "Insufficient funds"
        );
        require(_betnum > 0 && _betnum <= boxesCount, "Incorrect bet number");
        require(
            msg.value >= minBet && msg.value <= maxBet,
            "Incorrect bet amount"
        );
        bets[msg.sender].push(Bet(block.number, msg.value, _betnum));

        emit BetPlaced(msg.sender, block.number, msg.value, _betnum);
    }

    /**
     * @dev Allows a user to claim their prize.
     */
    function getPrize() external {
        uint256 winAmount = calculateTotalWin(msg.sender);
        require(winAmount > 0, "You have not win");
        delete bets[msg.sender];
        payable(msg.sender).sendValue(winAmount);
        emit PrizeClaimed(msg.sender, winAmount);
    }

    /**
     * @dev Calculates the total prize amount for a user.
     * @param _user The address of the user.
     * @return The total prize amount.
     */
    function calculateTotalWin(address _user) public view returns (uint256) {
        uint256 totalWin;
        for (uint256 i = 0; i < bets[_user].length; i++) {
            totalWin += calculateWin(_user, i);
        }
        return totalWin;
    }

    /**
     * @dev Calculates the prize amount for a specific bet of a user.
     * @param _user The address of the user.
     * @param _betIndex The index of the bet in the user's array of bets.
     * @return The prize amount for the bet.
     */
    function calculateWin(
        address _user,
        uint256 _betIndex
    ) public view returns (uint256) {
        Bet storage _bet = bets[_user][_betIndex];
        uint256 winNum = getRand(_bet.blockNumber);
        if (_bet.betNumber == winNum) {
            return (_bet.amount * winCoefficient) / COEFFICIENT_DENOMINATOR;
        } else {
            return 0;
        }
    }

    /**
     * @dev Estimates the potential reward for a given bet amount.
     * @param _amount The amount of FTN staked in the bet.
     * @return The estimated reward based on the bet amount and the global win coefficient.
     * @notice This function provides an estimate of the potential reward for a bet
     * based on the specified amount and the globally defined win coefficient.
     * The estimate does not represent the actual reward claimable by the user.
     * To claim the actual reward, use the 'getPrize' function after the bet outcome is determined.
     * @dev The win coefficient used for the calculation is set by the contract owner.
     */
    function estimateAvialableReward(uint256 _amount) public view returns(uint256){
        return _amount * winCoefficient / COEFFICIENT_DENOMINATOR;
    }

    /**
     * @dev Generates a pseudo-random number based on a past block's hash.
     * @param _blockNumber The block number to use for randomness.
     * @return The pseudo-random number.
     */
    function getRand(uint256 _blockNumber) internal view returns (uint256) {
        require(block.number > _blockNumber, "Block number out of range");
        return
            (uint256(keccak256(abi.encodePacked((blockhash(_blockNumber))))) %
                boxesCount) + 1;
    }

    function checkWin(bytes32 _blockHash, uint256 betNum, uint256 betAmount) external view returns(uint256){
        uint256 winNum = (uint256(keccak256(abi.encodePacked(_blockHash)))%
                boxesCount) + 1;
        if(winNum == betNum){
            return betAmount * winCoefficient / COEFFICIENT_DENOMINATOR;
        }
        else{
            return 0;
        }
    }
}